Permanent motivation in Logo

Károly Farkas
John von Neumann Computer Society
H-1054 Budapest, Báthory u. 16, Hungary,
tel.: (361)132-9349,
fax:(361) 131-8140,
email:h1033tit@ella.hu

Abstract

The paper shows an example how we explain and use logo-pedagogy. As far as we are concerned, one of the main thesis of this paradigm is self-teaching. Playful Informatics, which we constructed is suitable for children from 6 to 12 years. The focus of this method is on play using toys and games in conjunction with the computer and some other informatics instruments.

Keywords

Permanent motivation, game, step by step, Papert, Skinner

1 Introduction

At conferences dealing with Logo it can often be heard that the real value given by Seymour Papert is not Logo program language itself, but Logo-pedagogy. My decade-long experience also shows that Logo-like teaching is really interesting, enjoyable and so really effective.

• With the following example I would like to demonstrate how I can develop children's thinking by their high-level activity. With this, I will use LogoWriter, the most widespread version of Logo in Hungary.
• Beside Papert, Skinner also has to be mentioned: teaching material is to be divided into small steps, and after each step feedback is to be established.
• The following teaching unit can be applied at different age-groups after the necessary preliminary Logo-training. At intensive summer camps on informatics, we regularly play this with children between the age of 8 and 14, after one week of training.
• The objective is to prepare a program for a computer game. Man has been able to catch moving objects for a very long time. This is an instinctive ability and it is amusing as well. Early computer games were also based on this. Everybody knows wall tennis. Children come across several games of this kind but with Logo they can also make their own version, which they can use and develop further, according to their taste and knowledge. To each level of demands, different items of Logo language and programming knowledge are connected.

2 Level 1: a shape is moving on the monitor screen

We want the turtle to fall to the bottom of the screen. Even nursery school children understand the simplest way of animating the turtle: repeat one step back. If the first attempt is something like this:

repeat 80 [bk 1] ;the turtle will move fast.

The turtle's movement will be slower if it rests for a while after each step. The proper command:

repeat 80 [bk 1 wait 1]

The necessary value after "wait" has to be found by the children through experimenting.

The command-line should be named "fall":

to fall
repeat 80 [bk 1 wait 1]
end

Now we want not the turtle, but a ball to move. My nursery school pupils also know the solution for this: the turtle has to take the shape of the ball. Let's draw the ball as shape No. 12.

Before starting the program "fall", the turtle should set everything in starting position, no line to be drawn, then it is to take the shape of the ball:

to prepare1
rg pu
getshapes setsh 12
end

Now the "show" will consist of two parts: "prepare" and "fall".

to show
prepare1
fall
end

3 Level 2: two moving objects

Let the racket be at the bottom of the screen. As we want the racket and the ball to move separately, the racket should be an other turtle. Let's call it No. 1 ( the previous, "main" turtle is No. 0), let it be green, let it not draw a line, go to the bottom of the screen and take the shape of the racket, given as shape No. 50.

The "prepare" procedure will be this:

to prepare2
rg pu
getshapes setsh 12
tell 1 setc 7 pu setpos [0 - 60] setsh 50
end

4 Level 3: The movement has to be controlled

A valuable feature of Logo is that we can - in an enjoyable way - introduce the children such operations that used to be unknown for adults, for example controlling and regulating. The turtle is not only able to move, but to sense as well. I usually demonstrate this before teaching the above tasks, first not with the screen-turtle, but with one of the floor-turtles.

In this lecture I would like to demonstrate this simple cybernetic feedback with the Logo floor-turtle. It will move forward until it bumps into something. Now, at the signal of the micro-switch placed in its nose, the turtle will change the direction of movement. Instead of the micro-switch, the direction can also be changed by the control signal of the optosensor.

The screen-turtle can also receive different signals. For example, it is able to sense the colour of the given part of the screen it has just reached. In the wall-tennis game, if the racket is green, reaching a green field on the screen can be a warning to change direction. To do this, the turtle has to "nose about":

to ball
tell 0
if colorunder = 7 [turn]
bk 1 wait 1
ball
end

to turn
seth 180 - heading
end

The ball will bounce from the wall at the top of the screen if the wall is green. So let us draw a green line there:

to line
setpos [-155 80] pd setx 155 pu
end

This line can be drawn by the turtle before it takes the role of the racket:

to prepare3
rg pu
getshapes setsh 12
tell 1 setc 7 pu line setpos [0-80] setsh 50
end

Now the ball will bounce to and fro between the racket and the wall if we give the command:

to bounce
prepare3
ball
end

5 Level 4: permanent control of the game

At start, let the ball fall at a random direction: seth 30 + random 60. So we have to move the racket to receive the ball. We can move it with pressing the keys R and L.

In the tennis-procedure either the ball or the racket is moving. Both in the racket- and the ball-procedure the turtle has to check if we want to move the racket, that is, the tennis
-procedure has to follow. So we have to rewrite the former ball-procedure as procedure "ball4". The structure of the program is only understandable for better pupils at younger groups, but it is a very good example for teaching program-structure for teen-age students.

to tennis
ifelse key? [racket][ball]
end

to racket
tell 1
make "signal readchar
if :signal = "r [seth 270]
if :signal = "l [seth 90]
fd 5
tennis
end

to ball4
tell 0
if colorunder = 7 [turn]
bk 1 wait 1
tennis
end

6 Level 5: further development of the game on one's own

Those who have reached this point at Logo-like way of thinking, probably wil be able for further improvement of the program: changing the speed of the ball and of the racket, the size of the racket, applying two rackets or more balls, having the ball bounced from side walls, having obsatacles that "swallow" the ball, and so on.

7 Conclusion

As far as I am concerned Logo is perfectly suitable to develop thinking from nursery school to university level.

8 Reference

1. Farkas K., Informatics Games for Developing Children's Thinking Ability. Informatics and Changes in Learning, ed. D.C: Johnson, B. Samways. IFIP Transaction A-34, 1993. p. 87-93.